Bestand:Uniaxial.png

Grootte van deze voorvertoning: 240 × 600 pixels. Andere resoluties: 96 × 240 pixels | 192 × 480 pixels.

Oorspronkelijk bestand ‎(800 × 2.000 pixels, bestandsgrootte: 26 kB, MIME-type: image/png)

Dit is een bestand van Wikimedia Commons.
Onderstaande beschrijving komt van de beschrijving van het bestand daar.

Dit diagram zou opnieuw moeten worden aangemaakt als een SVG-bestand door vectorafbeeldingen te gebruiken. Dit heeft een aantal voordelen; zie Commons:Media for cleanup voor meer informatie. Als er een SVG-formaat van deze afbeelding bestaat, dan deze graag uploaden. Nadat u dit heeft gedaan, gelieve dit sjabloon te vervangen door het sjabloon {{vector version available|nieuwe bestandsnaam.svg}} op deze afbeeldingspagina.

Beschrijving

Author: en:user:AndrewKepert
Toolchain: MetaPost and TeX.
Source: below
Description: Illustration of a typical member of each of 7 infinite families of 3D point groups.
Destination: en:Point groups in three dimensions.
Permission: GFDL / CC

Source code

Instructions: on a system with a modern TeTeX or similar installed save the following two files, then run

mpost uniaxial && pdftex uniaxial

You will then need to use ghostscript or similar to make a raster image out of the pdf.

Source code author: en:user:AndrewKepert

Source code license: GPL

Deze PNG rasterafbeelding is gemaakt met MetaPost

Broncode

PostScript code

picture pic[];
 pair pt[],pt[]n,pt[]e,pt[]w,pt[]s,pt[]ne,pt[]nw,pt[]se,pt[]sw;
 pair ux,uy,uz;
 path unitcircle; unitcircle=fullcircle scaled 2;
 boolean front[];
 color colour[];
 path p[];
 
 u=16;
 ux=.4*down*u;
 uy=right*2u;
 uz=up*.5u;
 
 transform xyplane[];
 (0,0) transformed xyplane0 = (0,0);
 (1,0) transformed xyplane0 = ux;
 (0,1) transformed xyplane0 = uy;
 for i = -1 step 1/16 until 1:
     xyplane[i]=xyplane[0] shifted (i*uz);
 endfor
 
 theta=10;
 alpha=8;
 
 N:=6;
 
 for i = -1 step .5 until N+1:
     pt[i]   = right rotated  theta        rotated (360i/N) transformed xyplane0;
     front[i]= ypart pt[i] < ypart xyplane0;
     pt[i]e  = right rotated (theta+alpha) rotated (360i/N) transformed xyplane0;
     pt[i]w  = right rotated (theta-alpha) rotated (360i/N) transformed xyplane0;
     pt[i]n  = right rotated  theta        rotated (360i/N) transformed xyplane[.75];
     pt[i]ne = right rotated (theta+alpha) rotated (360i/N) transformed xyplane[.75];
     pt[i]nw = right rotated (theta-alpha) rotated (360i/N) transformed xyplane[.75];
     pt[i]s  = right rotated  theta        rotated (360i/N) transformed xyplane[-.75];
     pt[i]se = right rotated (theta+alpha) rotated (360i/N) transformed xyplane[-.75];
     pt[i]sw = right rotated (theta-alpha) rotated (360i/N) transformed xyplane[-.75];
 endfor
 
 t0=directiontime uz of (unitcircle transformed xyplane0);
 t1=directiontime -uz of (unitcircle transformed xyplane0);
 t2=t0+length unitcircle;
 
 path backface,frontface;
 backface:=(subpath (t0,t1) of unitcircle transformed xyplane[1])
         -- (subpath (t1,t0) of unitcircle transformed xyplane[-1])
         -- cycle;
 frontface:= (subpath (t1,t2) of unitcircle transformed xyplane[1])
         -- (subpath (t2,t1) of unitcircle transformed xyplane[-1])
         -- cycle;
 
 colour0:=(.8,.85,1);
 colour1:=.8[black,colour0];
 colour2:=.6[black,colour1];
 
 def constructribbon(expr delta)=
     % stuff on back face
     pic1:=image( for i = 0 step delta until N-eps: if not front[i]: fill p[i]; fi endfor
         fill (subpath (t0,t1) of unitcircle transformed xyplane[1/16])
         -- (subpath (t1,t0) of unitcircle transformed xyplane[-1/16])
         -- cycle;);
     % stuff on front face
     pic2:=image( for i = 0 step delta until N-eps: if  front[i]: fill p[i]; fi endfor
         fill (subpath (t1,t2) of unitcircle transformed xyplane[1/16])
         -- (subpath (t2,t1) of unitcircle transformed xyplane[-1/16])
         -- cycle;);
     % all of back face
     pic0:=image(fill frontface withcolor colour0;
         fill backface withcolor colour1;
         draw pic1 withcolor colour2);
     fill backface withcolor colour0;
     fill frontface withcolor colour0;
     draw pic1;
     clip pic0 to frontface;
     draw pic0;
     draw pic2;
     draw unitcircle transformed xyplane[1] withpen pencircle scaled 0.2 withcolor colour1;
     draw subpath (t2,t1) of unitcircle transformed xyplane[-1] withpen pencircle scaled 0.2 withcolor colour1;
 enddef;
 
 beginfig(1)
     for i=0 upto N-1:
         p[i]:= pt[i]--pt[i]w--pt[i]ne--pt[i]e--cycle;
     endfor
     constructribbon(1);
 endfig;
 
 beginfig(2)
     for i=0 upto N-1:
         p[i]:=  pt[i]w--pt[i]ne--pt[i]se--cycle ;
     endfor
     constructribbon(1);
 endfig;
 
 beginfig(3)
     for i=0 upto N-1:
         p[i]:= pt[i]--pt[i]e--pt[i]n--pt[i]w--cycle ;
     endfor
     constructribbon(1);
 endfig;
 
 beginfig(4)
     for i=0 upto N-1:
         %p[i]:=  pt[i]--pt[i]ne--pt[i]e--pt[i]--pt[i]sw--pt[i]w--cycle ;
         p[i]:=          pt[i]ne--pt[i]e--       pt[i]sw--pt[i]w--cycle ;
     endfor
     constructribbon(1);
 endfig;
 
 beginfig(5)
     for i=0 upto N-1:
         p[i]:=  pt[i]n--pt[i]e--pt[i]s--pt[i]w--cycle ;
     endfor
     constructribbon(1);
 endfig;
 
 beginfig(6)
     for i=0 upto N-1:
         p[i]:=  pt[i]--pt[i]e--pt[i]n--pt[i]w--cycle ;
         p[i+.5]:=  pt[i+.5]--pt[i+.5]e--pt[i+.5]s--pt[i+.5]w--cycle ;
     endfor
     constructribbon(1/2);
 endfig;
 
 beginfig(7)
     for i=0 upto N-1:
         if odd i:
             p[i]:= pt[i]--pt[i]w--pt[i]ne--pt[i]e--cycle;
         else:
             p[i]:= pt[i]--pt[i]w--pt[i]se--pt[i]e--cycle;
         fi
     endfor
     constructribbon(1);
 endfig;
 
 
 bye

Data

\input supp-pdf
 {\tabskip=5pt  \lineskiplimit=5pt  \lineskip=\lineskiplimit
 \halign{\hfil#\hfil&\hfil$\vcenter{\convertMPtoPDF{#}{1}{1}}$\hfil\cr
     $C_6$&uniaxial.1\cr
     $C_{6h}$&uniaxial.2\cr
     $C_{6v}$&uniaxial.3\cr
     $D_6$&uniaxial.4\cr
     $D_{6h}$&uniaxial.5\cr
     $D_{6d}$&uniaxial.6\cr
     $S_6$&uniaxial.7\cr
     }
 }
 \bye

Licentie

Ik, de auteursrechthebbende van dit werk, maak het hierbij onder de volgende licenties beschikbaar:

Toestemming wordt verleend voor het kopiëren, verspreiden en/of wijzigen van dit document onder de voorwaarden van de GNU-licentie voor vrije documentatie, versie 1.2 of enige latere versie als gepubliceerd door de Free Software Foundation; zonder Invariant Sections, zonder Front-Cover Texts, en zonder Back-Cover Texts. Een kopie van de licentie is opgenomen in de sectie GNU-licentie voor vrije documentatie.

	Dit bestand is gelicenseerd onder de Creative Commons-licentie Naamsvermelding-Gelijk delen 3.0 Unported

	De gebruiker mag: Delen – het werk kopiëren, verspreiden en doorgeven Remixen – afgeleide werken maken Onder de volgende voorwaarden: naamsvermelding – U moet op een gepaste manier aan naamsvermelding doen, een link naar de licentie geven, en aangeven of er wijzigingen in het werk zijn aangebracht. U mag dit op elke redelijke manier doen, maar niet zodanig dat de indruk wordt gewekt dat de licentiegever instemt met uw werk of uw gebruik van zijn werk. Gelijk delen – Als u het werk heeft geremixt, veranderd, of erop heeft voortgebouwd, moet u het gewijzigde materiaal verspreiden onder dezelfde licentie als het oorspronkelijke werk, of een daarmee compatibele licentie.
	Deze licentietag is toegevoegd aan dit bestand in verband met de GFDL licentie-update.CC BY-SA 3.0truetrue

Dit bestand is gelicenseerd onder de Creative Commons-licenties Naamsvermelding-Gelijk delen 2.5 Algemeen, 2.0 Algemeen en 1.0 Algemeen.

De gebruiker mag:

Delen – het werk kopiëren, verspreiden en doorgeven
Remixen – afgeleide werken maken

Onder de volgende voorwaarden:

naamsvermelding – U moet op een gepaste manier aan naamsvermelding doen, een link naar de licentie geven, en aangeven of er wijzigingen in het werk zijn aangebracht. U mag dit op elke redelijke manier doen, maar niet zodanig dat de indruk wordt gewekt dat de licentiegever instemt met uw werk of uw gebruik van zijn werk.
Gelijk delen – Als u het werk heeft geremixt, veranderd, of erop heeft voortgebouwd, moet u het gewijzigde materiaal verspreiden onder dezelfde licentie als het oorspronkelijke werk, of een daarmee compatibele licentie.

U mag zelf één van de licenties kiezen.

Bestandsgeschiedenis

Klik op een datum/tijd om het bestand te zien zoals het destijds was.

	Datum/tijd	Miniatuur	Afmetingen	Gebruiker	Opmerking
huidige versie	5 jul 2006 10:28		800 × 2.000 (26 kB)	AndrewKepert~commonswiki	Author: user:en:AndrewKepert Toolchain: MetaPost and TeX. Source: will be uploaded Description: Illustration of a typical member of each of 7 infinite families of 3D point groups. Destination: en:Point groups in three dimensions. Permission: GF

Bestandsgebruik

Dit bestand wordt op de volgende pagina gebruikt:

Symmetriegroep

Globaal bestandsgebruik

De volgende andere wiki's gebruiken dit bestand:

Gebruikt op en.wikipedia.org
- Point groups in three dimensions
Gebruikt op es.wikipedia.org
- Grupos de puntos en tres dimensiones
Gebruikt op id.wikipedia.org
- Pengguna:Klasüo/bak pasir/Arsip 15
- Grup titik dalam tiga dimensi
Gebruikt op ru.wikipedia.org
- Точечная группа в трёхмерном пространстве
Gebruikt op zh.wikipedia.org
- 三維點群

Bestand:Uniaxial.png

Inhoud

Beschrijving

Source code

PostScript code

Data

Licentie

Bijschriften

Items getoond in dit bestand

beeldt af

auteursrechtenstatus

auteursrechtelijk beschermd

licentie

Creative Commons Attribution-ShareAlike 1.0 Generic ^Engels

GNU Free Documentation License, version 1.2 or later ^Engels

Creative Commons Attribution-ShareAlike 2.0 Generic ^Engels

Creative Commons Attribution-ShareAlike 2.5 Generic ^Engels

Creative Commons Naamsvermelding-GelijkDelen 3.0 Unported

Bestandsgeschiedenis

Bestandsgebruik

Globaal bestandsgebruik

Beschrijving

Source code

PostScript code

Data

Licentie

Bijschriften

Items getoond in dit bestand

beeldt af

auteursrechtenstatus

auteursrechtelijk beschermd

licentie

Creative Commons Attribution-ShareAlike 1.0 Generic Engels

GNU Free Documentation License, version 1.2 or later Engels

Creative Commons Attribution-ShareAlike 2.0 Generic Engels

Creative Commons Attribution-ShareAlike 2.5 Generic Engels

Creative Commons Naamsvermelding-GelijkDelen 3.0 Unported

Bestandsgeschiedenis

Bestandsgebruik

Globaal bestandsgebruik

Creative Commons Attribution-ShareAlike 1.0 Generic ^Engels

GNU Free Documentation License, version 1.2 or later ^Engels

Creative Commons Attribution-ShareAlike 2.0 Generic ^Engels

Creative Commons Attribution-ShareAlike 2.5 Generic ^Engels