Beschrijving

Beschrijving3D-Link.PNG	Two curves with linking number 4. L8a14. Created with POV-Ray.
Datum	7 september 2007, 06:56 (originele uploaddatum)
Bron	Verplaatst vanaf en.wikipedia naar Commons. by Keyi (overleg · bijdragen).
Auteur	Jim.belk
Toestemming (Hergebruik van dit bestand)	Public domainPublic domainfalsefalse   Dit bestand is door Jim.belk op Wikimedia Commons, in het publieke domein geplaatst. Dit is wereldwijd van toepassing. In sommige landen is dit niet mogelijk; in die gevallen geldt: Jim.belk verleent iedereen het recht dit bestand voor ieder doel te gebruiken, zonder enige aanvullende voorwaarden, met uitzondering van de geldende wettelijke beperkingen. .

Oorspronkelijk uploadlogboek

Notes

Made with POVRay for Windows, version 3.6.

Source Code

#include "colors.inc"

#declare AxisLength = 3;
#declare FrameWidth = 0.01;

global_settings { assumed_gamma 1.0}
plane { <0,0,1>, -0.5 pigment {color rgb <.9,.9,.9> } finish {ambient 0.4 diffuse 0.5} }
camera { location <0.1,0.5,4.5> sky <0,0,1> right <-1,1,0>/sqrt(2) look_at <0,0,0> }
light_source { <0, -2, 10> color White area_light <1, 0, 0>, <0, 1, 0>, 3, 3 adaptive 1 jitter }

#declare R = 1.5;  // radius to center circle of torus
#declare r = 0.5;  // radius of torus cross-section  
#declare r_tube = 0.1;  // thickness of tube
              
#macro tpoint(theta,phi)
  <(R + r*cos(phi))*cos(theta), (R + r*cos(phi))*sin(theta), r*sin(phi)>
#end

sphere_sweep
  {
  cubic_spline 35,
  #declare Index = 0;
  #while(Index < 35)
    tpoint( (Index-1)*pi/16, (Index-1)*pi/4), r_tube
    #declare Index = Index + 1;
  #end
  finish {phong 1} pigment {color Blue}
  }

sphere_sweep
  {
  cubic_spline 35,
  #declare Index = 0;
  #while(Index < 35)
    tpoint( (Index-1)*pi/16, (Index+3)*pi/4), r_tube
    #declare Index = Index + 1;
  #end
  finish {phong 1} pigment {color Red}
  }

Complied to 600 x 600, with 0.3 anti-aliasing