Bestand:Mexicopop.svg

# POPULATION PYRAMID
 
scale = 1000000 # ADJUST AS NECESSARY
# The increment would better be automatic, but "set xtics" doesn't
# allow to specify start only.
increment = 1 # ADJUST THIS AS NECESSARY
gap_width = 0.11 # ADJUST THIS AS NECESSARY
 
# ADJUST TITLES AS NECESSARY
# set title "Mexico - 2009"
set xlabel "Population of Mexico, 2009 (millions)"
 
# Input file contains comma-separated values fields
set datafile separator ","
 
# Plot to dummy device and retrieve the male/female population range
set term unknown
 
set autoscale xfix
plot "data.csv" using ($4/scale):2, "data.csv" using (-$5/scale):2
 
range_male = (GPVAL_X_MAX > -GPVAL_X_MIN) ? GPVAL_X_MAX : -GPVAL_X_MIN
range_female = range_male
central_gap = (range_male + range_female) * gap_width
 
set term svg size 800,500 dynamic font "sans-serif"
 
set style data boxxyerrorbars
set style fill solid 0.25 border
 
# Y axis has no lines and tics, only labels which are shifted to bar medians
set yzeroaxis linewidth 0
set ytics axis scale 0
set ytics offset 0, second 1.8
set autoscale yfix
set format y ""
 
# X axis is labeled from zero onwards, with the given increment
set xtics nomirror 0,increment
 
plot [-range_female-central_gap:range_male]\
 "data.csv" using (0):2:(0):($4/scale):2:($2+5)\
  title "Males" linetype rgb "#296dcc",\
 "data.csv" using (-gap_width * 5):($2+1.8):2 title "" with labels
 
set key left Left reverse
 
plot [range_female:-central_gap-range_male]\
 "data.csv" using (0):2:(0):($5/scale):2:($2+5)\
  title "Females" linetype rgb "#aa3f74"