Beschrijving

Licentie

Ik, de auteursrechthebbende van dit werk, maak het hierbij onder de volgende licentie beschikbaar:

Dit bestand is gelicenseerd onder de Creative Commons-licentie Naamsvermelding 3.0 Unported

De gebruiker mag:

• Delen – het werk kopiëren, verspreiden en doorgeven
• Remixen – afgeleide werken maken

Onder de volgende voorwaarden:

• naamsvermelding – U moet op een gepaste manier aan naamsvermelding doen, een link naar de licentie geven, en aangeven of er wijzigingen in het werk zijn aangebracht. U mag dit op elke redelijke manier doen, maar niet zodanig dat de indruk wordt gewekt dat de licentiegever instemt met uw werk of uw gebruik van zijn werk.

https://creativecommons.org/licenses/by/3.0CC BY 3.0 Creative Commons Attribution 3.0 truetrue

Gnuplot source code

# EU lamp energy label, based on directive 98/11/EC
# http://eur-lex.europa.eu/LexUriServ/LexUriServ.do?uri=CELEX:31998L0011:EN:NOT
# this script was written for Gnuplot version 4.4, by Han-Kwang

reset

# labels for internationalization
NO_BALLAST = 'No integrated ballast'
XLABELTEXT = 'Luminous flux (lm)'
YLABELTEXT = 'Electrical power (W)'


# Power in watt for class A, given luminous flux Q

# PA_f: fluorescence lamps without ballast
PA_f(Q) = 0.15*sqrt(Q) + 0.0097*Q

# PA_o: all other fluorescent lamps
PA_o(Q) = 0.24*sqrt(Q) + 0.0103*Q

# Reference power for EEI
PR(Q) = (Q > 34) ? 0.88*sqrt(Q) + 0.049*Q : 0.2*Q

# upper limits for classes B-F
PB(Q) = PR(Q)*0.60
PC(Q) = PR(Q)*0.80
PD(Q) = PR(Q)*0.95
PE(Q) = PR(Q)*1.10
PF(Q) = PR(Q)*1.30

set xlab XLABELTEXT
set ylab YLABELTEXT

set xra [0:3000]
set yra [0:300]
set mxtics 5
set mytics 5
unset key

lx = 1600
set lab 1 'A' at lx,(PA_o(lx))/2
set lab 2 'B' at lx,(PA_o(lx)+PB(lx))/2
set lab 3 'C' at lx,(PB(lx)+PC(lx))/2
set lab 4 'D' at lx,(PC(lx)+PD(lx))/2
set lab 5 'E' at lx,(PD(lx)+PE(lx))/2
set lab 6 'F' at lx,(PE(lx)+PF(lx))/2
set lab 7 'G' at lx,1.1*PF(lx)

set lab 10 NO_BALLAST at 2900,10 right
set arrow 1 from 2570,15 to 2660,PA_f(2660)-1 lw 1.3 size screen 0.02,20


set sty line 11 lt 1 lw 1.3 lc rgbcolor '#33a357'
set sty line 1 lt 1 lw 3 lc rgbcolor '#33a357'
set sty line 2 lt 1 lw 3 lc rgbcolor '#79b752'
set sty line 3 lt 1 lw 3 lc rgbcolor '#c3d545'
set sty line 4 lt 1 lw 3 lc rgbcolor '#efe124' # modified for better contrast
set sty line 5 lt 1 lw 3 lc rgbcolor '#edb731'
set sty line 6 lt 1 lw 3 lc rgbcolor '#d66f2c'
set sty line 7 lt 1 lw 3 lc rgbcolor '#cc232a'

set sty data lines
set grid

set term svg size 600,400
set outp 'EU_lamp_energy_classes.svg'

set multiplot
plot \
    PA_f(x) ls 11, \
    PA_o(x) ls 1, \
    PB(x)   ls 2, \
    PC(x)   ls 3, \
    PD(x)   ls 4, \
    PE(x)   ls 5, \
    PF(x)   ls 6

set size 0.4,0.53
unset xlab
unset ylab
unset label
set origin 0.12,0.44
set xra [0:400]
set yra [0:40]
set xtics 100
unset ytics
set format y ''
set ytics 10
set y2tics 10
set grid xtics y2tics
set object 1 rect from graph -0.05, graph -0.15 to graph 1.2, graph 1.05 behind
set object 1 rect fc rgb "white" fillstyle solid 1.0 border rgb "white"

replot

unset multi

set outp