Beschrijving

POV-Ray image description code

/*
================================================
Model of the voltaic pile
------------------------------------------------
Created by Søren Peo Pedersen - see my user page
at http://da.wikipedia.org/wiki/Bruger:Peo
================================================
*/

#declare txtCopper=texture {    // Defines the "material" for
  pigment {color rgb <1,.8,.6>} // copper discs and terminal
  finish {ambient .2 reflection rgb <1,.8,.6> metallic phong 1}
  }

#declare txtZinc=texture {      // Defines the "material" for
  pigment {color rgb .7}        // zinc discs and terminal
  finish {ambient .3 reflection rgb .4 metallic phong 1}
  }

#declare txtSoakDisc=texture {  // Defines the "material" for
  pigment {                     // the solution-soaked discs.
    gradient y                  // "layered" pattern...
    color_map {                 // with an odd, pale green 
      [0 color rgb <.45,.5,.4>] // scale of colors...
      [1 color rgb <.85,.9,.8>]
      }
    scale .1                    // Tiny "layers"...
    turbulence .8               // ... all "curled" up.
    }
  finish {      // Surface properties...:
    ambient .4
    phong 1     // Makes this "wet" stuff glitter in the light
    }
  normal {bumps 1 scale .07}  // Rough, bumpy surface
  }


#macro MetalDisc(Sign,HasTerminal)
merge {      // General shape of metal disc:
  cylinder {<0,.1,0>,<0,.9,0>,6}    // Generally a cylindrical
  cylinder {0,<0,1,0>,5.9}          // shape, but with nice 0.1-
  torus {5.9,.1 translate <0,.9,0>} // radius "round edges" that
  torus {5.9,.1 translate <0,.1,0>} // won't cut your fingers ;-)
  #if (HasTerminal) // If there is a terminal...:
    cylinder {<0,.5,0>,<-7,.5,-4>,.2} // A cylindrical "rod" from edge of disc
    sphere {<-7,.5,-4>,.6}  // Spere at end of terminal "rod".
  #end
  texture {   // Texture and the polarity "stamped" on the edge of metal discs
    object {
      union {
        box {<-.3,.46,-5>,<.3,.54,-7>}  // "-" on disc edge
        box {<-7.4,.4,-6>,<-6.6,.6,-4>} // "-" on terminal
        difference {                          // Circle around
          cylinder {<0,.5,-5>,<0,.5,-7>,.4}   // sign on edge
          cylinder {<0,.5,-4>,<0,.5,-8>,.37}  // of the disc
          }
        #if (Sign>0)  // If positive polarity, add a vertical line to
          box {<-.04,.2,-5>,<.04,.8,-7>}  // sign on disc edge 
          box {<-7.1,.1,-6>,<-6.9,.9,-4>} // sign on an eventual terminal
        #end
        }
      texture {#if (Sign>0) txtCopper #else txtZinc #end} // Choice of metal
      texture {       // Choice of color for "stamped" sign on disc edges;
        #if (Sign>0)  // red for positive, blue for negative.
          pigment {color rgb <1,0,0>} finish {ambient .4}
        #else
          pigment {color rgb <0,0,1>} finish {ambient .4}
        #end} 
      }
    }
  }
#end

#macro Cell(Terminal) // Macro that "builds" one whole cell:
union {
  #object {MetalDisc(1,(Terminal=1))} // Positive (copper) disc
  cylinder {<0,1,0>,<0,1.5,0>,5.7 texture {txtSoakDisc} // Soaked disc in between.
    #if (Terminal=3) translate <1.5,0,-1> #end          // If Therminal=3, "petrude"
    }                                                   // disc a bit from the stack. 
  #object {MetalDisc(-1,(Terminal=2)) // Negative (zinc) disc
    translate <0,1.5,0>}
  }
#end

// Build the entire voltaic pile:
#object {Cell(2) translate < 0, 12.5,0>}
#object {Cell(3) translate < 0, 10,0>}
#object {Cell(0) translate <0, 7.5,0>}
#object {Cell(0) translate <1, 5.0,-.2>}
#object {Cell(0) translate < 0, 2.5,0>}
#object {Cell(1)}

// Annotatons: Require the TrueType font "timesbd" (Times New Roman in boldface) to be
// installed. To get rid of the annotations, remove the entire #union statement below:
#union {
  text {ttf "timesbd.ttf","1",.001,0 translate <4.5,-.9,0>}
  text {ttf "timesbd.ttf","2",.001,0 translate <3.2,-1.7,0>}
  text {ttf "timesbd.ttf","3",.001,0 translate <-4.8,3.4,0>}
  text {ttf "timesbd.ttf","4",.001,0 translate <-4.6,-4.1,0>}
  text {ttf "timesbd.ttf","5",.001,0 translate <3.9,1.7,0>}
  text {ttf "timesbd.ttf","6",.001,0 translate <3.2,-0.0,0>}
  text {ttf "times.ttf","}",.001,0 scale 2.7 translate <3.7,-1.15,0>}
  pigment {color rgb 0} finish {ambient 1 diffuse 0}
  no_shadow no_reflection
  scale .0004
  translate <0,0,-50.98>
  rotate <11.30993247402021308647450543834,0,0>  
  translate <0,7,0>
  }

camera {                    // Defines viewpoint
  up <0,1,0> right <1,0,0>  // and line of sight
  location <0,17,-50>       // for the image
  look_at <0,6.8,0>
  angle 22
  }

#declare Spotty=pigment { // Pattern for "spotty
  bumps                   // surroundings", to
  color_map {             // make metals look
    [0 color rgb 0]       // "really metallic".
    [1 color rgb 1]
    }
  scale .3
  }

sky_sphere {pigment { // Combine spotty pattern
  gradient z          // with a neutral, white
  pigment_map {       // background for the a-
    [0 Spotty]        // rea the camera "sees".
    [.974 Spotty]
    [.974 color rgb 1]
    [1 color rgb 1]
    }
  translate -.5
  scale 2
  rotate <11.30993247402021308647450543834,0,0>  
  }}

light_source {<-100,150,-200> color rgb 1}  // Light sources surroun-
light_source {<200,50,100> color rgb 1}     // ding the motif.

Licentie

Ik, de auteursrechthebbende van dit werk, maak het hierbij onder de volgende licenties beschikbaar:

Toestemming wordt verleend voor het kopiëren, verspreiden en/of wijzigen van dit document onder de voorwaarden van de GNU-licentie voor vrije documentatie, versie 1.2 of enige latere versie als gepubliceerd door de Free Software Foundation; zonder Invariant Sections, zonder Front-Cover Texts, en zonder Back-Cover Texts. Een kopie van de licentie is opgenomen in de sectie GNU-licentie voor vrije documentatie.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	Dit bestand is gelicenseerd onder de Creative Commons-licentie Naamsvermelding-Gelijk delen 3.0 Unported
	De gebruiker mag: Delen – het werk kopiëren, verspreiden en doorgeven Remixen – afgeleide werken maken Onder de volgende voorwaarden: naamsvermelding – U moet op een gepaste manier aan naamsvermelding doen, een link naar de licentie geven, en aangeven of er wijzigingen in het werk zijn aangebracht. U mag dit op elke redelijke manier doen, maar niet zodanig dat de indruk wordt gewekt dat de licentiegever instemt met uw werk of uw gebruik van zijn werk. Gelijk delen – Als u het werk heeft geremixt, veranderd, of erop heeft voortgebouwd, moet u het gewijzigde materiaal verspreiden onder dezelfde licentie als het oorspronkelijke werk, of een daarmee compatibele licentie.
	Deze licentietag is toegevoegd aan dit bestand in verband met de GFDL licentie-update.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

U mag zelf één van de licenties kiezen.